Bezprzewodowe czujniki temperatury wew. i zew. + wizualizacja danych + dobry regulator 3,3V !

Kolejny wpis i kolejny czujnik temperatury ? 
Tak wyszło 😂 Lecz dziś zajmiemy się płytką ESP8266 z znanym nam już DS18B20.

Założenia:

• małe rozmiary
• energooszczędność
• ładne wykresy
• monitorowanie napięcia zasilania i jakości sygnału Wi-Fi
  

Użyte elementy:

• ESP8266-12e wraz z podstawką
• Czujnik temperatury DS18B20
• Ogniwo Li-Ion 18650
• Ładowarka do ogniw TP4056 wraz z zabezpieczeniem przed zbyt dużym rozładowaniem
• Stabilizator HT7333
• Kondensator 2200uF
• Rezystor 4,7kOhm

Rys.1 Schemat połączeń płytki

Zasilanie

Ponieważ ogniwo 18650 wraz z zabezpieczeniem dostarcza od 4,2 do 2,5 V ,a ESP8266 działa stabilnie przy 3,3V należy stabilizować napięcie.

Najważniejszy parametr jakiego szukamy w dokumentacji to "voltage drop-out" czyli jaki najmniejszy spadek napięcia będzie na stabilizatorze.

Popularny LM1117 nie nadałby się zbyt gdyż spadek w nim to około 1-1,2V więc potrzebowalibyśmy zasilać go przynajmniej 4,3-4,5V.

Z pomocą przychodzi nam stabilizator HT7333 którego spadek napięcia to tylko 90mV !

Dodatkowo koszt 10 sztuk u Chińczyków to około 1$!

Zastosowałem również kondensator elektrolityczny o pojemności 2200uF aby ograniczyć "piki" poboru prądu przez ESP.

Rys.2 Nota katalogowa HT7333

Stabilizator pasuje idealnie do podstawki do naszego ESP 

Rys.3 Przykład kiepskiego lutowania

Usypianie:

Z moich pomiarów wynika że  ESP podczas łączenia się z siecią Wi-Fi oraz wysyłając dane na serwer pobiera 70-73mA podczas uśpienia tylko 0,23mA! To świetny wynik, dzięki tak głębokiemu uśpieniu nasz czujnik będzie bardzo długo działał na jednym ogniwie.

    ESP.deepSleep(3600000000,WAKE_RF_DEFAULT);

Wartość 3600000000 to godzina w mikrosekundach.

Samo usypianie realizowane jest programowo, należy pamiętać aby pin GPIO16 podłączyć do resetu. Odpowiada on za reset urządzenia po określonym interwale czasu.

Wizualizacja danych:

Na rynku jest sporo serwisów umożliwiających magazynowanie i wizualizację danych wysyłanych przez nasze urządzenia. Oczywiście moglibyśmy zbudować własny tego typu system chociażby na RPi Zero. Po przeglądnięciu kilku serwisów zdecydowałem się jednak na io.adafruit.com. 

2 czujniki (w pokoju i na balkonie) działają już około miesiąca i nie było problemów z serwisem.

Rys.4 Wykresy z io.adafruit.com

Sam serwis jest bardzo łatwy w obsłudze. Po rejestracji otrzymujemy swój indywidualny klucz "AIO KEY" który należy zadeklarować w programie

#define AIO_KEY "INDYWIDUALNY KLUCZ ADAFRUIT"

możemy go sprawdzić w zakładce "settings" na swoim koncie io.adafruit.com. Przy pierwszej wysyłce danych do serwisu zostaną stworzone "feeds" z taką nazwą jaka została podana w programie

sendToAIOFeed("temperatura", temp);
przykładowo do "temperatura" wysyła zmienną temp.

Jeśli już mamy jakieś dane wysłane do serwisu, wchodzimy w zakładkę Dashboards i tworzymy nowy. Gdy mamy nowy "dashboard" wchodzimy w niego i możemy dodawać wykresy i zegary aby wizualizować dane. Cały proces jest bardzo prosty i nie powinien sprawić trudności 😂

Działanie programu:

ESP8266 łączy się z siecią domową, odczytuje dane : temperaturę, napięcie zasilania i siłę sygnału Wi-Fi, wysyła dane na serwer adafruit i usypia się na godzinę. Wbudowany timer nie jest na tyle dokładny aby odliczyć dokładnie godzinę przy głębokim uśpieniu dlatego zazwyczaj jest to 53-55 minut.

ADC_MODE(ADC_VCC); //ustawiane adc jako odczyt napięcia zasilania

#include <ESP8266WiFi.h>

#include <math.h>

#include <Adafruit_IO_Client.h>

float temp; //zmienna temp zmiennoprzecinkowa aby wysyłać dokładny pomiar

int WiFiStrength = 0; 

#include <OneWire.h> //ds18b20

#include <DallasTemperature.h>

#define ONE_WIRE_BUS 5 // do pinu GPIO5 podłączony czujnik ds18b20

OneWire oneWire(ONE_WIRE_BUS);

DallasTemperature sensors(&oneWire);

#define SSID "NAZWA SIECI WIFI"

#define PASSWORD "HASŁO DO WIFI"

#define AIO_KEY "INDYWIDUALNY KLUCZ ADAFRUIT"

void setup() {

  delay(10);

  connectToWiFi();

  sensors.begin();

}

void connectToWiFi(){

  WiFi.begin(SSID, PASSWORD);

  while (WiFi.status() != WL_CONNECTED) {

    delay(500);

  }

}

void loop() {

    sensors.requestTemperatures();

    temp=sensors.getTempCByIndex(0); // przypisanie odczytu do zmiennej temp

    double volts = ESP.getVcc(); // przypisanie odczytu do zmiennej volts

    WiFiStrength = WiFi.RSSI(); // pobranie dBm z ESP8266

    sendToAIOFeed("napiecie", volts); // 

    sendToAIOFeed("sygnal", WiFiStrength);

    sendToAIOFeed("temperatura", temp);

    ESP.deepSleep(3600000000,WAKE_RF_DEFAULT); // usypianie na konkretny czas

    delay(100);

}

void sendToAIOFeed(const char* feed, double val){ //wysyłanie do adafruit

  WiFiClient client;

  Adafruit_IO_Client aio = Adafruit_IO_Client(client, AIO_KEY);

  Adafruit_IO_Feed testFeed = aio.getFeed(feed);

  aio.begin();

  testFeed.send(val);

}

Wersja zewnętrzna została wyposażona w dwa ogniwa 18650 połączone równolegle. Jest zamknięta w obudowie zmontowanej z doniczki i kilku podstawek z wyciętym dnem tak aby była cyrkulacja powietrza a jednocześnie woda nie dostawała się do środka. Ogniwa 18650 jak czytamy w dokumentacji mogą działać do -20 stopni !

Rys.5 nota katalogowa ogniw 18650

Rys.6 Mało estetyczna obudowa

Jeśli ktoś byłby zainteresowany odczytami z moich czujników to zapraszam na

https://io.adafruit.com/ktryb/dashboards/esp8266